NTFS圧縮・暗号化の解除

■概要

NTFSファイル形式にするとフォルダおよびファイルに対して圧縮もしくは暗号化をすることができます。ただセキュリティ対策のため、独自の暗号化ソフトなどを導入すると、それらとバッティングするために解除が必要になる場合があります。そのような場合に使用するとよいかもしれません。

■プログラムコード (compactcipher.bat)

@echo off

rem ----------------------------------------------------------
rem NTFS圧縮・暗号化の解除BAT Ver1.0
rem ----------------------------------------------------------

rem ■変更箇所（対象のパス指定）■
set FolderPath=C:\,D:\

rem 必要に応じて C:\,D:\ を変更してください。
rem 指定はフルパスで行い、複数ある場合は,で区切ってください。
rem C:\新しいフォルダ
rem 上記のようにパスにスペースが入る場合は
rem "C:\新しいフォルダ" のように""を付けてください。

:Menu
cls
echo -------------------------------------------------------
echo NTFS圧縮・暗号化の解除
echo -------------------------------------------------------
echo.
echo 対象のパス
echo %FolderPath%
echo.
echo -------------------------------------------------------
echo 1:処理実行
echo q:終了
echo -------------------------------------------------------

rem 判定キーの初期化
set Slt=nul

rem 選択値の入力を求める
set /p Slt=入力：

rem 条件分岐
if '%Slt%'=='1' goto Set_1
if '%Slt%'=='q' goto :eof

rem 指定文字以外の入力がある場合は、メニューに戻る
goto Menu

rem -------------------------------------------------------
:Set_1

rem ■NTFS圧縮の解除
for %%a in (%FolderPath%) do compact /s:%%a /a /f /i /q /u
rem これは圧縮解除用なので圧縮をかけたい場合は /u を /c にしてください。

rem ■NTFS暗号化の解除
rem for %%p in (%FolderPath%) do attrib -h -r %%p\* /d /s
rem 読み取り専用のフォルダ・ファイルは暗号化解除できなので
rem 必要に応じて2行上の rem を消してください。
rem その場合は指定したフォルダおよびファイルの
rem 読み取り専用および隠しファイル属性が消えます。

for %%a in (%FolderPath%) do cipher /s:%%a /a /f /h /i /q /d
rem これは暗号化解除用なので暗号化したい場合は /d を /e にしてください。

echo.
echo 処理が完了しました。何かキーを押してください。
pause > nul

■使用方法

1.	「プログラムのダウンロード」よりバッチファイルをダウンロードしてください。
2.	ファイルを開いて対象のパスを変更してください。（必要に応じて）
3.	バッチファイルをマウスでダブルクリックしてください。
4.	対象のパスを確認してから1を入力して「Enter」キーを押してください。

■解説

NTFS圧縮にcompact コマンド、暗号化にcipherコマンドを使用し対象フォルダをforで指定しています。
圧縮解除のみや暗号化解除のみにしたい場合はそれぞれの for の前に rem を記入してください。

■プログラムのダウンロード

[ TOP ]　[ コマンドプロンプト ]　[ HOME ]