ディスクパーティションの作成 [Windows PE用]

■概要

Windows PEの環境でディスクパーティション（Cドライブなど）を作成するバッチファイルです。
ハード構成によってDiskやVolumeの番号が違うので環境に合わせて修正してください。

■プログラムコード (partition.bat)

□partition.bat

@echo off

rem -------------------------------------------------
rem ディスクパーティションの作成 Ver1.0
rem -------------------------------------------------

rem ☆---------------------------------------------------☆
■変更箇所■
rem DISKPART用ファイルのパスとファイル名
rem パスかファイル名に変更がある場合は、以下を変更する

rem 全ドライブの消去
rem Cドライブに全容量
set Program1=X:\tool\diskpart\all.txt
rem Cドライブ20GB
set Program2=X:\tool\diskpart\c20.txt
rem Cドライブ40GB
set Program3=X:\tool\diskpart\c40.txt

rem ☆---------------------------------------------------☆
echo ----------------------------------------------------------------
echo ディスクパーティションの作成をしますか？
echo ----------------------------------------------------------------
echo 1:全ドライブを消去後、Cドライブに全容量を割り当てる
echo 2:全ドライブを消去後、Cドライブに20GBを割り当てる
echo 3:全ドライブを消去後、Cドライブに40GBを割り当てる
echo 無記入・[1-3]以外を入力した場合はNoになります
echo ----------------------------------------------------------------

rem 判定キーの初期化
set Slt=Nul

set /p Slt=入力：
IF '%Slt%'=='1' goto Set1
IF '%Slt%'=='2' goto Set2
IF '%Slt%'=='3' goto Set3
goto :eof

:Set1
diskpart /s %Program1%
goto :FormatC

:Set2
diskpart /s %Program2%
goto :FormatC

:Set3
diskpart /s %Program3%
goto :FormatC

:FormatC
rem Cドライブのクイックフォーマット
echo y | format C: /fs:ntfs /Q /V:
echo Cドライブを作成しました。
goto :eof

□all.txt

select disk 0
clean
create partition primary
assign letter=C
active

□c20.txt

select disk 0
clean
create partition primary size=20480
assign letter=C
active

□c40.txt

select disk 0
clean
create partition primary size=40960
assign letter=C
active

■使用方法

1.	「プログラムのダウンロード」よりバッチファイルをダウンロードしてください。
2.	圧縮ファイルの解凍後、Windows PE用のmountフォルダ内にコピーしてください。
3.	Windows PEのプロンプト画面で本バッチファイルを実行させてください。
4.	Menu画面が表示されるので、処理番号を入力し、[Enter]キーを押してください。

■参照URL

	ディスクパーティション・ドライブ文字 (diskpart.bat)
	Diskpart コマンドラインユーティリティについて
	DiskPart

■プログラムのダウンロード

[ TOP ]　[ コマンドプロンプト ]　[ HOME ]