IPアドレスの設定　[Windows PE用]

■概要

Windows PEの環境でIPアドレス・DNSを固定で割り当てるバッチファイルです。
Windows PEの環境でネットワーク名「ローカルエリア接続」を指定すると日本語がいけないらしく設定ができなかったので、ネットワーク名の代わりにインデックス番号を使用します。
有線用NICのインデックス番号はおそらく2だと思いますが、増設した場合や違う場合もあるのでインデックス番号の確認と手動設定時のサポート画面を表示できるようにしています。

■プログラムコード (static.bat)

@echo off

rem -------------------------------------------------
rem IPアドレスの設定BAT Ver1.1
rem -------------------------------------------------

rem -------------------------------------------------------
rem ■変更箇所■
rem インデックス番号
set Idx=2

rem サブネットマスク
set Subnet=255.255.255.0

rem デフォルトゲートウェイ
set Dfgy=192.168.0.1

rem DNSサーバ
set DnsSv=192.168.0.1

rem -------------------------------------------------------

:Menu
cls
echo ------------------------------------------------
echo □■　Menu　■□
echo ------------------------------------------------
echo 1:固定IPアドレス
echo 2:インデックス番号の確認
echo 3:IPアドレスの確認
echo q:終了
echo ------------------------------------------------

rem 判定キーの初期化
set Slt=nul

rem 選択値の入力を求める
set /p Slt=入力：

rem 条件分岐
if '%Slt%'=='1' goto Set_1
if '%Slt%'=='2' goto Set_2
if '%Slt%'=='3' goto Set_3
if '%Slt%'=='q' goto :eof

rem 指定文字以外の入力がある場合は、メニューに戻る
goto Menu

:Set_1
rem ----------------------------------------------------
rem ■IPアドレスを固定で取得
rem ----------------------------------------------------
rem IPアドレス＆DNSの設定

echo ローカルエリア接続に設定するIPアドレスを入力してください
echo 例：192.168.0.1
set /p Ipadd=入力：192.168.0.
rem ■変更箇所：上の192.168.0.を実環境に合わせて変更する。■

echo 固定IPアドレスを設定します。しばらくお待ちください。

netsh interface ip set dnsserver name=%Idx% source=static address=%DnsSv% register=none
netsh interface ip set address name=%Idx% source=static address=192.168.0.%Ipadd% mask=%Subnet% gateway=%Dfgy%
rem ■変更箇所：上の192.168.0.を実環境に合わせて変更する。■

echo 固定IPアドレスを設定しました。
pause

rem 処理終了
goto :Menu

:Set_2
rem ----------------------------------------------------
rem ■インデックス番号の確認
rem ----------------------------------------------------

echo ローカルエリア接続のインデックス番号を確認する[ Idx ]
netsh interface ip show interface
echo 手動設定
echo netsh interface ip set dnsserver [インデックス番号] static [DNSサーバのIPアドレス] none
echo netsh interface ip set address [インデックス番号] static [IPアドレス] [サブネットマスク] [デフォルトゲートウェイ]

rem 処理終了
goto :eof

:Set_3
rem ---------------------------------------------------------
rem ■IPアドレスの確認
rem ---------------------------------------------------------
rem IPアドレスなどを表示させる
ipconfig /all
echo.
pause

rem 処理終了
goto :Menu

■使用方法

1.	「プログラムのダウンロード」よりバッチファイルをダウンロードしてください。
2.	バッチファイルを開き、変更箇所の値を変更してください。
3.	Windows PE用のmountフォルダ内にコピーしてください。
4.	Windows PEのプロンプト画面で本バッチファイルを実行させてください。
5.	Menu画面が表示されるので、処理番号を入力し、[Enter]キーを押してください。

■変更する場合のポイント

1.	インデックス番号を2以外でも設定することが多い場合（ネットワークカードを増設して使用など）はIPアドレスの入力（set /p Ipadd=入力：192.168.0.）の前か後に set /p Idx=インデックス番号の入力: という1行を追加してインデックス番号を入力できるようにした方がよいでしょう。
2.	IPアドレスの入力を192.168.0.1.としていますが192.168..のように変更箇所が増える場合は set /p Ipadd=入力：192.168. として netsh interface ip set address name=%Idx% source=static address=192.168.0.%Ipadd% のaddress=192.168.0.%Ipadd% を address=192.168.%Ipadd% としてください。

■参考

IPアドレスの設定（ipaddress.bat）

■プログラムのダウンロード

[ TOP ]　[ コマンドプロンプト ]　[ HOME ]

IPアドレスの設定 [Windows PE用]

IPアドレスの設定　[Windows PE用]