USBメモリお手軽フォーマット

■概要

USBメモリ・MOなどのリムーバブルメディアをFAT32形式でクイックフォーマットします。
Ver1.0の場合はバッチファイルの実行前に必ずUSBメモリなどのドライブ文字を確認し、本バッチファイルの変更箇所を変更してください。
（Vectorでも同一のものがダウンロードできます。)
Ver2.0はバッチファイルの実行中にドライブ文字を指定できるようにしました。

■プログラムコード (um-format.bat)

@echo off

rem -------------------------------------------------
rem USBメモリお手軽フォーマットBAT Ver1.0
rem -------------------------------------------------

rem -------------------------------------------------------
rem ■変更箇所■
rem USBメモリのドライブ文字を必ず確認してください。
rem Drive=の後のUをUSBメモリのドライブ文字に変更してください。

rem ドライブ文字の指定
set Drive=U

rem -------------------------------------------------------

cls
echo -----------------------------------------------------------------
echo フォーマットしますか？
echo -----------------------------------------------------------------
echo [警告]
echo ドライブ文字を必ず確認してください。
echo.
echo ドライブ文字 [ %Drive% ]
echo.
echo 実行する場合は入力:の後に1を入力し[Enter]キーを押してください。
echo -----------------------------------------------------------------
echo 1 : YES
echo 1以外 or 未入力: NO
echo -----------------------------------------------------------------

rem 判定キーの初期化
set Slt=nul

rem 選択値の入力を求める
set /p Slt=入力：

rem 条件分岐
if '%Slt%'=='1' goto Set_1

rem 指定文字以外の入力がある場合は、処理を終了する
goto :eof

:Set_1
rem ----------------------------------------------------
rem フォーマットの実行
rem ----------------------------------------------------
rem [設定内容]
rem ボリュームラベル(v) ：なし
rem ファイルシステム(fs) ：FAT32
rem フォーマットオプション(q)：クイックフォーマット
rem -------------------------------------------------

echo クイックフォーマットをしています。しばらくお待ちください。
echo Y | format %Drive%: /v: /fs:FAT32 /q > nul

echo フォーマットが終了しました。何かキーを押してください。
pause > nul

@echo off

rem -------------------------------------------------
rem USBメモリお手軽フォーマットBAT Ver2.0
rem -------------------------------------------------

:InputDriveName
cls
echo -----------------------------------------------------------------
echo フォーマットしたいドライブのドライブ文字を入力してください
echo 例：Uドライブをフォーマットしたい場合
echo u と入力し[Enter]キーを押してください。（大文字/小文字区別なし）
echo -----------------------------------------------------------------
set /p Drive=入力：

cls
echo -----------------------------------------------------------------
echo フォーマットしますか？
echo -----------------------------------------------------------------
echo [警告]
echo ドライブ文字を必ず確認してください。
echo.
echo ドライブ文字 [ %Drive% ]
echo.
echo 実行する場合は入力:の後に1を入力し[Enter]キーを押してください。
echo -----------------------------------------------------------------
echo 1 : YES
echo 2 : ドライブ文字の指定をし直す
echo 1,2以外 or 未入力: NO
echo -----------------------------------------------------------------

rem 判定キーの初期化
set Slt=nul

rem 選択値の入力を求める
set /p Slt=入力：

rem 条件分岐
if '%Slt%'=='1' goto Set_1
if '%Slt%'=='2' goto InputDriveName

rem 指定文字以外の入力がある場合は、処理を終了する
goto :eof

:Set_1
rem ----------------------------------------------------
rem フォーマットの実行
rem ----------------------------------------------------
rem [設定内容]
rem ボリュームラベル(v) ：なし
rem ファイルシステム(fs) ：FAT32
rem フォーマットオプション(q)：クイックフォーマット
rem -------------------------------------------------

echo クイックフォーマットをしています。しばらくお待ちください。
echo Y | format %Drive%: /v: /fs:FAT32 /q > nul
if errorlevel 1 goto :NG

echo フォーマットが終了しました。何かキーを押してください。
pause > nul
goto :eof

:NG
echo エラーが発生しました。
echo 指定したドライブ文字[ %Drive% ]
echo ドライブ文字の指定が正しいか確認してください。
echo フォーマット対象のドライブ、ドライブ内のフォルダ、ファイルを
echo 開いている場合は閉じてから行ってください。
echo 処理を中止します。
pause > nul
goto :eof

■使用方法

1.	「プログラムのダウンロード」よりバッチファイルをダウンロードしてください。
2.	LZH形式で圧縮しているので解凍してください。
3.	バッチファイルを開き、変更箇所の値を変更してください。（Ver1.0のみ）
4.	バッチファイルをマウスでダブルクリックしてください。

■解説

USBメモリの場合、接続環境によりドライブ文字が異なるためドライブ文字の確認をだしています。
フォーマット形式をNTFSにしたい場合は、以下のマイクロソフトのページを参照してください。
ただし推奨はしていないようです。
リムーバブルメディアの NTFS フォーマットについて

■プログラムのダウンロード

[ TOP ]　[ コマンドプロンプト ]　[ HOME ]