ThanksgivingSoft

ハードディスクのお手入れ
■概要
チェックディスク・デフラグを実行させることができます。
ハードディスクの大容量化（数百GBがあたりまえ）に伴い処理時間が長くかかります。
十分に時間があるときに実行してください。
■プログラムコード (chkhdd.bat)
@echo off

rem -------------------------------------------------
rem ハードディスクのお手入れBAT Ver1.0
rem -------------------------------------------------

:Menu
cls
echo --------------------------------------------
echo ■　Menu　■
echo --------------------------------------------
echo 1:チェックディスクの実行
echo 2:システム起動時にディスクの自動検査
echo 3:不良ビット調査
echo 4:ディスクの分析(デフラグの必要性の有無)
echo 5:デフラグ
echo q:終了
echo --------------------------------------------

rem 判定キーの初期化
set Slt=nul

rem 選択値の入力を求める
set /p Slt=入力：

rem 条件分岐
if '%Slt%'=='1' goto Set_1
if '%Slt%'=='2' goto Set_2
if '%Slt%'=='3' goto Set_3
if '%Slt%'=='4' goto Set_4
if '%Slt%'=='5' goto Set_5
if '%Slt%'=='q' goto :eof

rem 指定文字以外の入力がある場合は、メニューに戻る
goto Menu

:Set_1
rem ----------------------------------------------------
rem ■チェックディスク
rem ----------------------------------------------------
echo 「ボリュームが別のプロセスで使用されているため・・・
echo 再起動時に・・・スケジュールしますか(Y/N)? 」
echo と表示された場合は、Yを選択してください。
echo.

rem @@@@@ ユーザー変更箇所 @@@@@
rem c:, d:はドライブ文字です。ご自身の環境に合わせ変更してください。
rem <例> Dドライブがない場合は、fsutil dirty query d: 行を削除する。
rem Eドライブもある場合は、fsutil dirty query e: 行を追加する。

echo ------------------------------------
echo ■Cドライブ
chkdsk /f /r c:
echo ------------------------------------
echo ■Dドライブ
chkdsk /f /r d:
echo ------------------------------------

rem @@@@@@@@@@@@@@@@@@@@@@@@@@@

rem 結果表示
echo ------------------------------------
echo 「ボリュームが別のプロセスで使用されているため・・・
echo 再起動時に・・・スケジュールしますか(Y/N)? 」
echo の表示後、Yを選択した場合は、OSを再起動してください。
echo.
pause

rem 処理終了
goto :eof

:Set_2
rem ----------------------------------------------------
rem ■システム起動時にディスクの自動検査
rem ----------------------------------------------------
chkntfs /D

rem 情報表示
echo システム起動時にすべてのディスクをチェックします。
echo エラーの可能性がある場合は、CHKDSKを実行します。
echo エラーがない場合は、普通にOSが起動します。
echo OSを再起動してください。
echo.
pause

rem 処理終了
goto :eof

:Set_3
rem ----------------------------------------------------
rem ■不良ビット調査
rem ----------------------------------------------------
rem ドライブに不良ビットが設定されている場合、デフラグは実行されません。
rem 各ドライブが Dirty ではありません。と表示されることを確認してください。

rem @@@@@ ユーザー変更箇所 @@@@@
rem c:, d:はドライブ文字です。ご自身の環境に合わせ変更してください。

fsutil dirty query c:
fsutil dirty query d:

rem @@@@@@@@@@@@@@@@@@@@@@@@@@@

rem 結果表示
echo ------------------------------------
echo 不良ビット調査をしました。
echo ボリューム - *: は Dirty です。 (*:ドライブ文字)と表示された場合は
echo ドライブに不良ビットが設定されています。
echo.
echo 何かキーを押すと、Menuに戻ります。
pause > nul

rem Menuに戻る
goto :Menu

:Set_4
rem ----------------------------------------------------
rem ■ディスクの分析(デフラグの必要性の有無)
rem ----------------------------------------------------

rem @@@@@ ユーザー変更箇所 @@@@@
rem c:, d:はドライブ文字です。ご自身の環境に合わせ変更してください。

echo ------------------------------------
echo ■Cドライブ
defrag -a c:
echo ------------------------------------
echo ■Dドライブ
defrag -a d:

rem @@@@@@@@@@@@@@@@@@@@@@@@@@@

rem 結果表示
echo.
echo ------------------------------------
echo 「このボリュームを最適化してください。」と表示された場合は、デフラグを実行してください。
echo.
echo 何かキーを押すと、Menuに戻ります。
pause > nul

rem Menuに戻る。
goto :Menu

:Set_5
rem ----------------------------------------------------
rem ■デフラグ
rem ----------------------------------------------------

rem @@@@@ ユーザー変更箇所 @@@@@
rem c:, d:はドライブ文字です。ご自身の環境に合わせ変更してください。

echo ------------------------------------
echo ■Cドライブ
defrag c:
echo ------------------------------------
echo ■Dドライブ
defrag d:

rem @@@@@@@@@@@@@@@@@@@@@@@@@@@

rem 結果表示
echo デフラグが終了しました。
echo.
pause

rem 処理終了
goto :eof
■使用方法
1. 「プログラムのダウンロード」よりバッチファイルをダウンロードしてください。
2. バッチファイルを開き、ユーザー変更箇所を変更してください。
3. バッチファイルをマウスでダブルクリックしてください。
4. Menu画面が表示されるので、処理番号を入力し、[Enter]キーを押してください。
■解説
コマンドプロンプトよりデフラグを実行することはできますが、処理状況が％表示されず、いつ終わるかわかりません。
PCに張り付いている場合は、デフラグツールで行ったほうが気分的によいでしょう。
ドライブが複数ある場合は、連続処理ができるので、実行してほったらかしておき気がついたら終わっていたという使用法がよいと思います。
■プログラムのダウンロード
　　ダウンロード
[ TOP ]　[ コマンドプロンプト ]　[ HOME ]