ショートカットの矢印の表示/非表示の切り替え

■概要

ショートカットの左下に表示される矢印を表示/非表示にします。
バッチファイルの実行後、OSの再起動が必要です。
（OSの再起動後に設定が反映されます。）

■プログラムコード (yajirushi.bat)

@echo off

rem -------------------------------------------------
rem ショートカットの矢印を表示/非表示にするBAT Ver1.0
rem -------------------------------------------------

:Menu
cls
echo -------------------------------------------
echo ショートカットの矢印の表示/非表示の切替
echo -------------------------------------------
echo 1:矢印の非表示
echo 2:矢印の表示
echo q:終了
echo -------------------------------------------
echo 注意：レジストリを変更します
echo -------------------------------------------

rem 判定キーの初期化
set Slt=nul

rem 選択値の入力を求める
set /p Slt=入力：

rem 条件分岐
if '%Slt%'=='1' goto Set_1
if '%Slt%'=='2' goto Set_2
if '%Slt%'=='q' goto :eof

rem 指定文字以外の入力がある場合は、メニューに戻る
goto Menu

:Set_1
rem ----------------------------------------------------
rem ■ショートカットの矢印を非表示にする
rem ----------------------------------------------------
reg delete "HKEY_CLASSES_ROOT\lnkfile" /f /v IsShortcut

rem 結果表示
echo OSを再起動してください。再起動後、矢印が非表示になります。
pause > nul

rem 処理終了
goto :eof

:Set_2
rem ----------------------------------------------------
rem ■ショートカットの矢印を表示する
rem ----------------------------------------------------
reg add "HKEY_CLASSES_ROOT\lnkfile" /f /v IsShortcut /t reg_sz

rem 結果表示
echo OSを再起動してください。再起動後、矢印が表示されます。
pause > nul

rem 処理終了
goto :eof

■使用方法

1.	「プログラムのダウンロード」よりバッチファイルをダウンロードしてください。
2.	バッチファイルをマウスでダブルクリックしてください。
3.	Menu画面が表示されるので、処理番号を入力し、[Enter]キーを押してください。
4.	OSを再起動してください。

■解説

ショートカットの矢印はHKEY_CLASSES_ROOT\lnkfileのIsShortcutを削除またはBakupIsShotcutなどに名前を変更すると非表示になります。

■プログラムのダウンロード

[ TOP ]　[ コマンドプロンプト ]　[ HOME ]