ProxyのON/OFFの切り替え

■概要

Internet Explorerのプロキシサーバーの設定を行います。
会社ではProxyサーバーを使用し、家ではProxyサーバーを使用しないでインターネットに接続する方は使用するとよいでしょう。

■プログラムコード (proxy.bat)

@echo off

rem -------------------------------------------------
rem ProxyをON/OFFにするBAT Ver1.0
rem -------------------------------------------------

:Menu
cls
echo --------------------------------------
echo ProxyのON/OFF切替
echo --------------------------------------
echo 1:Proxy ON
echo 2:Proxy OFF
echo q:終了
echo --------------------------------------
echo 注意：レジストリを変更します
echo --------------------------------------

rem 判定キーの初期化
set Slt=nul

rem 選択値の入力を求める
set /p Slt=入力：

rem 条件分岐
if '%Slt%'=='1' goto Set_1
if '%Slt%'=='2' goto Set_2
if '%Slt%'=='q' goto :eof

rem 指定文字以外の入力がある場合は、メニューに戻る
goto Menu

:Set_1
rem ----------------------------------------------------
rem ■ProxyをONにする
rem ----------------------------------------------------
reg add "HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Internet Settings" /f /v ProxyEnable /t reg_dword /d 1
reg add "HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Internet Settings" /f /v ProxyServer /t reg_sz /d proxyserver.jp:8080
reg add "HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Internet Settings" /f /v ProxyOverride /t reg_sz /d "<local>"

rem 結果表示
echo Proxy ON
pause

rem 処理終了
goto :eof

:Set_2
rem ----------------------------------------------------
rem ■ProxyをOFFにする
rem ----------------------------------------------------
reg add "HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Internet Settings" /f /v ProxyEnable /t reg_dword /d 0

rem 結果表示
echo Proxy OFF
pause

rem 処理終了
goto :eof

■使用方法

1.	「プログラムのダウンロード」よりバッチファイルをダウンロードしてください。
2.	バッチファイルを開き、■ProxyをONにするの2行下、proxyserver.jp:8080を変更してください。
3.	バッチファイルをマウスでダブルクリックしてください。
4.	Menu画面が表示されるので、処理番号を入力し、[Enter]キーを押してください。

■解説

レジストリの値を変更することでInternet Explorerのプロキシサーバーの設定を変更することができます。

■プログラムのダウンロード

[ TOP ]　[ コマンドプロンプト ]　[ HOME ]