ThanksgivingSoft

IPアドレスの設定
■概要
IPアドレスを固定で割り当てたりDHCPで取得したりできるバッチファイルです。
会社では固定、家ではDHCPでIPアドレスが割振られる場合などで使用するとよいでしょう。
■プログラムコード (ipaddress.bat)
@echo off

rem -------------------------------------------------
rem IPアドレスの設定BAT Ver1.1
rem -------------------------------------------------

rem -------------------------------------------------------
rem ■変更箇所■
rem ネットワーク名
set Ntname="ローカル エリア接続"

rem 固定で割当てるIPアドレス
set Ipadd=192.168.0.10

rem サブネットマスク
set Subnet=255.255.255.0

rem デフォルトゲートウェイ
set Dfgy=192.168.0.1

rem DNSサーバ1
set DnsSv1=192.168.0.1

rem DNSサーバ2
set DnsSv2=192.168.0.2
rem -------------------------------------------------------

:Menu
cls
echo ------------------------------------------------
echo □■　Menu　■□
echo ------------------------------------------------
echo 1:固定IPアドレス
echo 2:DHCP
echo 3:IPアドレスの確認
echo q:終了
echo ------------------------------------------------

rem 判定キーの初期化
set Slt=nul

rem 選択値の入力を求める
set /p Slt=入力：

rem 条件分岐
if '%Slt%'=='1' goto Set_1
if '%Slt%'=='2' goto Set_2
if '%Slt%'=='3' goto Set_3
if '%Slt%'=='q' goto :eof

rem 指定文字以外の入力がある場合は、メニューに戻る
goto Menu

:Set_1
:Loop
cls

rem ----------------------------------------------------
rem ■IPアドレスを固定で取得
rem ----------------------------------------------------
rem IPアドレス＆DNSの設定

echo ローカルエリア接続に設定するIPアドレスを入力してください
echo 例：192.168.0.1
set /p Ipadd=入力：

rem 入力値の確認
echo -----------------------------------------------
echo ■IPアドレスの確認■
echo.
echo 　IPアドレスは[ %Ipadd% ]です
echo.
echo -----------------------------------------------
echo r:IPアドレスの修正
echo [r]以外を入力した場合はYesになります
echo -----------------------------------------------

rem 判定キーの初期化
set Slt=nul

set /p Slt=確認入力：
if '%Slt%'=='r' goto loop

echo 固定IPアドレスを設定します。しばらくお待ちください。

netsh interface ip set dns name=%Ntname% source=static addr=%DnsSv1% register=non
netsh interface ip add dns name=%Ntname% addr=%DnsSv2% index=2
netsh interface ip set add name=%Ntname% source=static addr=%Ipadd% mask=%Subnet% gateway=%Dfgy% gwmetric=1

echo 固定IPアドレスを設定しました。
pause

rem 処理終了
goto :Menu

:Set_2
rem ----------------------------------------------------
rem ■IPアドレスをDHCPで取得
rem ----------------------------------------------------
rem DHCPの設定
echo DHCPの設定をします。しばらくお待ちください。

netsh interface ip set dns name=%Ntname% source=dhcp register=non
netsh interface ip set add name=%Ntname% source=dhcp

echo DHCPの設定をしました。
pause

rem 処理終了
goto :Menu

:Set_3
rem ---------------------------------------------------------
rem ■IPアドレスの確認
rem ---------------------------------------------------------
rem IPアドレスなどを表示させる
ipconfig /all
echo.
pause

rem 処理終了
goto :Menu
■使用方法
1. 「プログラムのダウンロード」よりバッチファイルをダウンロードしてください。
2. バッチファイルを開き、変更箇所の値を変更してください。
3. バッチファイルをマウスでダブルクリックしてください。
4. Menu画面が表示されるので、処理番号を入力し、[Enter]キーを押してください。
■解説
・ IPアドレスやDNSの値を設定するにはnetshコマンドを使用します。
・ 設定を行う対象はネットワークのプロパティを開いたときに表示されている名前で判断をします。
無線LANの場合は変更箇所のNtnameを[ワイヤレス ネットワーク接続]など表示されている名前に変更してください。
・ DNSサーバが3つ以上ある場合は、以下の行を追加し
netsh interface ip add dns name=%Ntname% addr=%DnsSv2% index=2
DnsSv2にDNSサーバのIPアドレスを、ｉｎｄｅｘに3、４・・と優先順に数値を入力してください。
■プログラムのダウンロード
　　ダウンロード
[ TOP ]　[ コマンドプロンプト ]　[ HOME ]