ユーザーを作成し、指定したグループに登録する

■概要

ユーザーアカウントを事前に指定した初期パスワードで作成し、指定したローカルグループに追加します。

■プログラムコード (useradd.bat)

@echo off

rem ------------------------------------------------------
rem ユーザーを作成し指定したグループに登録するBAT Ver1.0
rem ------------------------------------------------------

rem -------------------------------------------------------
rem ■変更箇所■
rem ユーザーアカウントを登録するローカルグループを指定してください
set UserGroup=administrators

rem ユーザーアカウントの初期パスワードを指定してください
set ShokiPass=password

rem -------------------------------------------------------

:Menu
cls
echo --------------------------------------
echo □■　Menu　■□
echo --------------------------------------
echo 1:ユーザーアカウントの追加
echo q:終了
echo --------------------------------------

rem 判定キーの初期化
set Slt=nul

rem 選択値の入力を求める
set /p Slt=入力：

rem 条件分岐
if '%Slt%'=='1' goto Set_1
if '%Slt%'=='q' goto :eof

rem 指定文字以外の入力がある場合は、メニューに戻る
goto Menu

:Set_1
cls
rem ----------------------------------------------------
rem ■ユーザーアカウントを追加する
rem ----------------------------------------------------
echo ---------------------------------------------
echo 登録するユーザーアカウントを入力してください
echo 例：tarou
echo ---------------------------------------------
set /p UserName=:

rem ユーザーアカウントの確認
echo --------------------------------------------------
echo ■ユーザーアカウントの確認■
echo --------------------------------------------------
echo.
echo ユーザーアカウント[ %UserName% ]
echo ローカルグループ [ %UserGroup% ]
echo.
echo -------------------------------------------------
echo 0:ユーザアカウントの修正
echo q:処理中断(終了)
echo [0,q]以外を入力した場合は処理続行
echo -------------------------------------------------

rem 判定キーの初期化
set Slt2=nul

rem 選択値の入力を求める
set /p Slt2=確認入力：

rem ユーザーアカウントを修正する場合の処理
if '%Slt2%'=='0' goto Set_1
if '%Slt2%'=='q' goto :eof

rem ----------------------------------------------------
rem ユーザーアカウントの追加
net user %UserName% %ShokiPass% /add /passwordchg:yes

rem ユーザーのローカルグループへの登録
net localgroup %UserGroup% %UserName% /add

rem 処理結果表示
echo ユーザーアカウント[ %UserName% ]を追加しました
pause

■使用方法

1.	「プログラムのダウンロード」よりバッチファイルをダウンロードしてください。
2.	バッチファイルを開き、変更箇所の値を変更してください。
3.	バッチファイルをマウスでダブルクリックしてください。
4.	Menu画面が表示されるので、処理番号を入力し、[Enter]キーを押してください。

■解説

登録するユーザーアカウントのグループと初期パスワードをそれぞれUserGroupとShokiPassで設定します。
初期値の場合は、Administratorsグループにパスワードがpasswordのユーザーアカウントが作成されます。　

■プログラムのダウンロード

[ TOP ]　[ コマンドプロンプト ]　[ HOME ]